MT4でのEAの作り方。雛形のソースコード

EA

MT4のEAづくりで難解なのは、実稼働させた時にエントリーしても、原因不明のエラーコードが返って来ることです。

それを極力避けた、OnTick関数内に、条件式さえ入れれば、EAが出来る雛形のMQL4ソースコードを公開します。売買部分の関数はラッパー関数化してます。

利確と損切りも、パラメータで設定して、何pipsでクローズするという作りにしてみました。ベースとしては、結構使えると思います。

目次

ソースコード

そのままコピペすれば、使えます。

#include <stdlib.mqh> 

#property copyright "Copyright 2022, Yanoteck"
#property link      "https://elite-collections.com/"
#property version   "0.1"
#property strict

#define MAGIC 202211281651
 
extern double Lots = 0.01;       //lots
extern int Slippage = 30;        //slipage
extern double Profitrate = 20;   //Take Profit 値幅(pips)
extern double SLrate = 20;       //Stop Loss 損切り(pips)

//グローバル変数
//大量エントリー回避用(チケット番号)
int g_ticket_no = 0;
 
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   g_ticket_no = 0;
 
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   g_ticket_no = 0;

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   //オーダーの有無とフラグのチェック
   if(g_ticket_no != 0){   //エントリー中?

      //オーダー情報なし。途中でSL、TPで強制決済した
      if(OrdersTotal() == 0){
      
         //グローバル変数の初期化
         g_ticket_no = 0;
      }
   }

	//売買の処理はここで書く
	
	//ロングの際の書き方
	//My_Long(Lots,Slippage,SLrate,Profitrate,MAGIC);
 
	//ショートの際の書き方
	//My_Short(Lots,Slippage,SLrate,Profitrate,MAGIC);
 
  }
 
//+------------------------------------------------------------------+
//| ロング
//| OP_BUYのエントリー。リトライあり
//| 引数: my_lot = ロット
//|       my_slipage = スリッページ
//|       my_sl = 損切り
//|       my_tp = 利益
//|
//| 戻値: チケット番号
//+------------------------------------------------------------------+
int My_Long(double my_lot,int my_slipage , double my_sl, double my_tp, int my_magic){
 
   int ticket_no=0;  //ticket no
   int errorcode=0;  // エラーコード
 
   double losscut_normalize=0;
   double profit_normalize=0;
   double losscut_rate=0;
   double profit_rate=0;
 
   if(g_ticket_no != 0){
       return -1;
   }

   // ロスカット価格
   losscut_rate  = Ask - ( 10 * Point() * my_sl); 
 
   // 決済価格
   profit_rate   = Ask + ( 10 * Point() * my_tp); 
 
 
   //正規化
   losscut_normalize = NormalizeDouble(losscut_rate,int(MarketInfo(Symbol(),MODE_DIGITS)));
   profit_normalize  = NormalizeDouble(profit_rate,int(MarketInfo(Symbol(),MODE_DIGITS)));
 
 
   //ロングエントリー処理
   ticket_no = OrderSend(Symbol(),OP_BUY,my_lot,Ask,my_slipage,losscut_normalize,profit_normalize,"Buy order",my_magic,0,clrGreen);
   printf("OrderSend OP_BUY , price=%f , sl=%f , tp=%f",Ask,losscut_normalize,profit_normalize);
 
   if(ticket_no < 0){
      errorcode = GetLastError();      // エラーコード取得
      printf("Send Error! error_code:%d , detail:%s ",errorcode , ErrorDescription(errorcode));
 
      //再設定
      losscut_rate  = Ask - ( 10 * Point() * my_sl); 
      profit_rate   = Ask + ( 10 * Point() * my_tp); 
      losscut_normalize = NormalizeDouble(losscut_rate,int(MarketInfo(Symbol(),MODE_DIGITS)));
      profit_normalize  = NormalizeDouble(profit_normalize,int(MarketInfo(Symbol(),MODE_DIGITS)));
 
      //オーダー送信と同時に損切り、利益設定エラー対策
      ticket_no = OrderSend(Symbol(),OP_BUY,my_lot,Ask,my_slipage,0,0,"Buy order",my_magic,0,clrGreen);
      printf("Resend OrderSend OP_BUY , price=%f , sl=%f , tp=%f",Ask,losscut_normalize,profit_normalize);
 
      //オーダー修正
      LimitStop_Set(ticket_no,OP_BUY,clrGreen);
 
   }else {
      printf("Send Done. Ticket NO = %d",ticket_no);
   }

   g_ticket_no = ticket_no;
   
   return ticket_no;
}
 
//+------------------------------------------------------------------+
//| ショート
//| OP_SELLのエントリー。リトライあり
//| 引数: my_lot = ロット
//|       my_slipage = スリッページ
//|       my_sl = 損切り
//|       my_tp = 利益
//|
//| 戻値: チケット番号
//+------------------------------------------------------------------+
int My_Short(double my_lot,int my_slipage , double my_sl, double my_tp, int my_magic){
 
   //ticket no
   int ticket_no=0;
   int errorcode=0;               // エラーコード
 
   double losscut_normalize=0;
   double profit_normalize=0;
   double losscut_rate=0;
   double profit_rate=0;

   if(g_ticket_no != 0){
       return -1;
   }
 
   // ロスカット価格
   losscut_rate  = Bid + ( 10 * Point() * my_sl); 
 
   // 決済価格
   profit_rate   = Bid - ( 10 * Point() * my_tp); 
 
 
   //正規化
   losscut_normalize = NormalizeDouble(losscut_rate,Digits());
   profit_normalize  = NormalizeDouble(profit_rate,Digits());
 
 
   //shortエントリー処理
   ticket_no = OrderSend(Symbol(),OP_SELL,my_lot,Bid,my_slipage,losscut_normalize,profit_normalize,"Sell order",my_magic,0,clrRed);
   printf("OrderSend OP_SELL , price=%f , sl=%f , tp=%f",Bid,losscut_normalize,profit_normalize);
 
   //エラー?
   if(ticket_no < 0){
      errorcode = GetLastError();      // エラーコード取得
      printf("Send Error! error_code:%d , detail:%s ",errorcode , ErrorDescription(errorcode));
 
     // 再設定
      losscut_rate  = Bid + ( 10 * Point() * my_sl); 
      profit_rate   = Bid - ( 10 * Point() * my_tp); 
      losscut_normalize = NormalizeDouble(losscut_rate,int(MarketInfo(Symbol(),MODE_DIGITS)));
      profit_normalize  = NormalizeDouble(profit_normalize,int(MarketInfo(Symbol(),MODE_DIGITS)));
 
      //オーダー送信と同時に損切り、利益設定エラー対策
      ticket_no = OrderSend(Symbol(),OP_SELL,my_lot,Bid,my_slipage,0,0,"Sell order",my_magic,0,clrRed);
      printf("Resend sOrderSend OP_SELL , price=%f , sl=%f , tp=%f",Bid,losscut_normalize,profit_normalize);
 
      //オーダー修正
      LimitStop_Set(ticket_no,OP_SELL,clrRed);
 
 
   }else {
      printf("Send Done. Ticket NO = %d",ticket_no);
   }

   g_ticket_no = ticket_no;
   return ticket_no; 
}
 
//+------------------------------------------------------------------+
//| エントリー中のポジションのリミット・ストップを変更
//|
//| 引数 int in_ticket_no = Ticket no
//|     int buysell_type = OP_SELL or OP_BUY
//|     color mycolor = 表示色
//+------------------------------------------------------------------+
void LimitStop_Set( int in_ticket_no, int buysell_type , color mycolor) {
 
    int    modify_resend_num;       //変更試行回数
    bool   modify_ret;              //変更判定
    int    errorcode;               //エラーコード 
//    bool   selbool;
    double limit_rate,stop_rate;
    int    my_ticket_no;
 
    // オーダー中のチケット選択(チケットNo指定)
//    selbool = OrderSelect(in_ticket_no, SELECT_BY_TICKET); 
 
    if (buysell_type == OP_BUY){
       limit_rate = OrderOpenPrice() + ( 10 * Point() * Profitrate);
       stop_rate  = OrderOpenPrice() - ( 10 * Point() * SLrate);
     }else{
       limit_rate = OrderOpenPrice() - ( 10 * Point() * Profitrate);
       stop_rate  = OrderOpenPrice() + ( 10 * Point() * SLrate);
    }
 
    //リミット価格のNormalize(正規化)
    limit_rate = NormalizeDouble(limit_rate , Digits() );
    
    //ストップロス価格を正規化
    stop_rate  = NormalizeDouble(stop_rate  , Digits() );
 
    //オーダーチケット
    my_ticket_no = OrderTicket();
 
    //オーダーの修正
    for( modify_resend_num = 0; modify_resend_num < 30; modify_resend_num++ ) {
        modify_ret = OrderModify(
                                 my_ticket_no,      // チケットNo
                                 OrderOpenPrice(),  // 注文価格
                                 stop_rate,            // ストップロス価格
                                 limit_rate,           // リミット価格
                                 OrderExpiration(), // 有効期限
                                 mycolor               // 色
 
                     );
 
        printf("OrderModify ticket_no:%d , sl=%f , tp=%f",my_ticket_no , stop_rate,limit_rate);
 
        if ( modify_ret == false ) {             // 注文変更拒否
            Sleep(300);                         // 300msec待ち
            errorcode = GetLastError();        // エラーコード取得
            printf( "[%d]Modify Error! error_code:%d ,detail:%s ",
                                        modify_resend_num+1, errorcode ,  ErrorDescription(errorcode));
        } else {                                 // 決済注文約定
            Print("Done. Ticket NO=",in_ticket_no);
            break;
        }
    }
}
 
//+------------------------------------------------------------------+
//| ポジション強制決済  Long
//| 引数 int my_magic = マジックナンバー
//+------------------------------------------------------------------+
void My_force_close_long(int my_magic){
   int i;
   int my_ticket_no;
   double my_lots;
   double my_price = NormalizeDouble(Ask,int(MarketInfo(Symbol(),MODE_DIGITS)));
   bool chk;
   int errorcode;
 
   for(i=0;i<OrdersTotal();i++){
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES) == false){
         break;
      }
 
      if(OrderMagicNumber() != my_magic || OrderSymbol() != Symbol()){
         continue;
      }
 
      my_ticket_no = OrderTicket();
      my_lots = OrderLots();
      
      //買いポジションのチェック
      if(OrderType() == OP_BUY){
         chk = OrderClose(my_ticket_no,my_lots,my_price,Slippage,White);
         printf("OrderClose ret=%d , ticket_no=%d , lots=%f , BUY price=%f",chk,my_ticket_no,my_lots,my_price);
         
         if(chk == False){
            errorcode = GetLastError();      // エラーコード取得
            printf("OrderClose Error! error_code:%d , detail:%s ",errorcode , ErrorDescription(errorcode));
         }else{
            printf("OrderClose Done!");
         }
         break;
      }

      break;
   }
   g_ticket_no = 0;
}
 
//+------------------------------------------------------------------+
//| ポジション強制決済 short
//| 引数 int my_magic = マジックナンバー
//+------------------------------------------------------------------+
void My_force_close_short(int my_magic){
   int i;
   int my_ticket_no;
   double my_lots;
   double my_price = NormalizeDouble(Ask,int(MarketInfo(Symbol(),MODE_DIGITS)));
   bool chk;
   int errorcode;
 
   for(i=0;i<OrdersTotal();i++){
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES) == false){
         break;
      }
 
      if(OrderMagicNumber() != my_magic || OrderSymbol() != Symbol()){
         continue;
      }
      
      my_ticket_no = OrderTicket();
      my_lots = OrderLots();
 
      //売りポジションのチェック
      if(OrderType() == OP_SELL){
         chk = OrderClose(my_ticket_no,my_lots,my_price,Slippage,White);
         printf("OrderClose ret=%d , ticket_no=%d , lots=%f , SELL price=%f",chk,my_ticket_no,my_lots,my_price);
 
         if(chk == False){
            errorcode = GetLastError();      // エラーコード取得
            printf("OrderClose Error! error_code:%d , detail:%s ",errorcode , ErrorDescription(errorcode));
         }else{
            printf("OrderClose Done!");
         }
 
         break;
      }

      break;
   }
   g_ticket_no = 0;
}

使い方

OnTick()内で、トレードロジックの条件式を書いて、自作ラッパー関数のMy_Longでロング、My_Shortをコールすればショート出来ます。例えば、移動平均線のクロスの場合は、以下のような感じで書きます。

void OnTick()
  {
   double ma_20   = iMA(NULL,PERIOD_CURRENT,20,0,MODE_SMA,PRICE_CLOSE,0);
   double ma_20_1 = iMA(NULL,PERIOD_CURRENT,20,0,MODE_SMA,PRICE_CLOSE,1);
   double ma_40   = iMA(NULL,PERIOD_CURRENT,40,0,MODE_SMA,PRICE_CLOSE,0);
   double ma_40_1 = iMA(NULL,PERIOD_CURRENT,40,0,MODE_SMA,PRICE_CLOSE,1);

	 //売買の処理はここで書く
   //MA20本と40本のゴールデンクロス
	 if(ma_40_1 > ma_20_1 && ma_40 < ma_20){
	   //ロング
	   //My_Long(Lots,Slippage,SLrate,Profitrate,MAGIC);
	 }

  }
細かい書き方については、別途記事を書きます。

TP(利確)、SL(損切り)もパラメータで設定出来ます。内部でpips計算しているので、pipsで引き渡せます。

エラーになる場合

動作確認済みのソースコードですが、実稼働させてOrderSendでエラーになる場合、以下を参考にしてください。

エラーコード130 invalid stops

僕は、仮想通貨のブログも運営しているのですが、これについては下記の記事にまとめました。詳しく知りたい方は、ご覧ください。

矢野テックの投資ブログ
MQL4でOrderSendエラーコード130 invalid stopsの解決策 バックテストでは正常に稼働するけど、リアル口座ではOrderSend時に、エラーコード130(Invalid Stops)が出てしまう。かなりあれこれ調べまくって、なんとかある程度は解決...

色々やってわかったことですが、以下が原因です。

エラーコード130が出たら、まずは以下を確認してみてください。

  • SL、TPが現在の価格に近すぎる
  • SL、TPの小数点が多すぎる
  • スリッページが低すぎる
僕がハマったのは、スリッページでした。スリッページが極めて低く設定したため、エラーになってました。取引所によって最小スリッページは異なるようです。

工夫している点

ラッパー関数内に、エントリーを大量実施を防ぐための処置を施してます。いわゆるフラグ処理です。これをやらないと、条件が合致すると、OnTickが呼ばれるたびに、実施されてしまいます。

int My_Long(double my_lot,int my_slipage , double my_sl, double my_tp, int my_magic){
 
   int ticket_no=0;  //ticket no
   int errorcode=0;  // エラーコード
 
   double losscut_normalize=0;
   double profit_normalize=0;
   double losscut_rate=0;
   double profit_rate=0;
 
   //この箇所↓
   if(g_ticket_no != 0){
       return -1;
   }

OnTickの冒頭で、SL、TPで強制決済済みの場合は、フラグOFFになる仕様です。

   //オーダーの有無とフラグのチェック
   if(g_ticket_no != 0){   //エントリー中?

      //オーダー情報なし。途中でSL、TPで強制決済した
      if(OrderSelect(g_ticket_no,SELECT_BY_TICKET,MODE_TRADES) == false){
      
         //グローバル変数の初期化
         g_ticket_no = 0;
      }
   }
プログラマーとしては、フラグ処理は嫌いなのですが、スマートな方法が思いつかなかったです。
よかったらシェアしてね!
  • URLをコピーしました!
  • URLをコピーしました!

この記事を書いた人

仮想通貨botや、MT4のEA開発、インジケーターなどを作ってます。このブログでは検証結果を書いていきたいと思ってます。

コメント

コメントする

目次